input_parser.f90

Go to the documentation of this file.

! ---------------------------------------------------------------------------------------
! Dice Quantum Monte Carlo
! ---------------------------------------------------------------------------------------
! MODULE: input parser
!
! DESCRIPTION:
!
! ---------------------------------------------------------------------------------------
 
module input_parser
 
    use shared_data
    use restart_fns
 
    implicit none
 
contains
 
 
! ---------------------------------------------------------------------------------------
! SECTION: Namelist Parsers
! ---------------------------------------------------------------------------------------
 
 
    ! -----------------------------------------------------------------------------------
    ! ROUTINE: read_control
    !
    ! DESCRIPTION:
    !
    ! PARAMETERS:
    ! -----------------------------------------------------------------------------------
    subroutine read_control(p_system, run_equil, run_restart, write_restart, restart_num, write_chains, write_log)
 
        ! Local variables
        character(len=10), intent(out) :: p_system
        logical, intent(out) :: run_equil, run_restart, write_restart, write_chains, write_log
        integer(int32), intent(out) :: restart_num    
 
        ! Define the namelist
        namelist /control/ p_system, run_equil, run_restart, write_restart, restart_num, write_chains, write_log
 
        ! Read the namelist
        read(nml=control, iostat=rc, unit=fu)
        if (rc /= 0) then
            error stop 'Error: Invalid CONTROL namelist format in file "params.txt".'
        end if
        
    end subroutine read_control
 
    ! -----------------------------------------------------------------------------------
    ! ROUTINE: read_QHO
    !
    ! DESCRIPTION:
    !
    ! PARAMETERS:
    ! -----------------------------------------------------------------------------------
    subroutine read_qho(QHO)
 
        ! Local variables
        type(qho_type), intent(out) :: QHO
 
        ! Define the namelist
        namelist /parameters/ qho
 
        ! Read the namelist
        read(nml=parameters, iostat=rc, unit=fu)
        if (rc /= 0) then
            error stop 'Error: Invalid PARAMETERS namelist for QHO p_system in file "params.txt".'
        end if
        
    end subroutine read_qho
 
    ! -----------------------------------------------------------------------------------
    ! ROUTINE: read_H2plus
    !
    ! DESCRIPTION:
    !
    ! PARAMETERS:
    ! -----------------------------------------------------------------------------------
    subroutine read_h2plus(H2plus)
 
        ! Local variables
        type(h2plus_type), intent(out) :: H2plus
 
        ! Define the namelist
        namelist /parameters/ h2plus
 
        ! Read the namelist
        read(nml=parameters, iostat=rc, unit=fu)
        if (rc /= 0) then
            error stop 'Error: Invalid PARAMETERS namelist for H2plus p_system in file "params.txt".'
        end if
        
    end subroutine read_h2plus
 
    ! -----------------------------------------------------------------------------------
    ! ROUTINE: read_H2
    !
    ! DESCRIPTION:
    !
    ! PARAMETERS:
    ! -----------------------------------------------------------------------------------
    subroutine read_h2(H2)
 
        ! Local variables
        type(h2_type), intent(out) :: H2
 
        ! Define the namelist
        namelist /parameters/ h2
 
        ! Read the namelist
        read(nml=parameters, iostat=rc, unit=fu)
        if (rc /= 0) then
            error stop 'Error: Invalid PARAMETERS namelist for H2 p_system in file "params.txt".'
        end if
        
    end subroutine read_h2
 
 
! ---------------------------------------------------------------------------------------
! SECTION: Input Main
! ---------------------------------------------------------------------------------------
 
 
    ! -----------------------------------------------------------------------------------
    ! ROUTINE: read_inputs
    !
    ! DESCRIPTION:
    !
    ! -----------------------------------------------------------------------------------
    subroutine read_inputs()
 
        ! Check if file 'params.txt' exists
        inquire(file='params.txt', iostat=rc)
        if (rc /= 0) then
            error stop 'Error: Input file "params.txt" does not exist.'
        end if
 
        ! Open the params.txt file
        open(action='read', file='params.txt', iostat=rc, newunit=fu)
 
        ! Read CONTROL namelist
        call read_control(p_system, run_equil, run_restart, write_restart, restart_num, write_chains, write_log)
 
        ! If p_system='test', return to main
        if (trim(p_system)=='test') then
            return
        endif
        
        ! For equilibration runs, modify the default steps
        if (run_equil) then
            select case (trim(p_system))
            case ('QHO')
                qho%steps = d_eqsteps_qho
            case ('H2plus')
                h2plus%steps = d_eqsteps_h2plus
            case ('H2')
                h2%steps = d_eqsteps_h2
            case default
                error stop 'Error: Invalid system definition.'
            end select
        endif
 
        ! Read PARAMETERS namelist of the defined problem
        select case (trim(p_system))
        case ('QHO')
            call read_qho(qho)
        case ('H2plus')
            call read_h2plus(h2plus)
        case ('H2')
            call read_h2(h2)
        case default
            error stop 'Error: Invalid system definition.'
        end select
 
        ! Close the params.txt file
        close(fu)
 
        ! For equilibration runs, ensure burn_step=0 & thin_step=1
        if (run_equil) then
            select case (trim(p_system))
            case ('QHO')
                qho%burn_step = 0
                qho%thin_step = 1
            case ('H2plus')
                h2plus%burn_step = 0
                h2plus%thin_step = 1
            case ('H2')
                h2%burn_step = 0
                h2%thin_step = 1
            case default
                error stop 'Error: Invalid system definition.'
            end select
        endif
 
        ! Find run steps and thin step for checks
        select case (trim(p_system))
        case ('QHO')
            run_steps = qho%steps - qho%burn_step
            tstep = qho%thin_step
        case ('H2plus')
            run_steps = h2plus%steps - h2plus%burn_step
            tstep = h2plus%thin_step
        case ('H2')
            run_steps = h2%steps - h2%burn_step
            tstep = h2%thin_step
        case default
            error stop 'Error: Invalid system definition.'
        end select
 
        ! For restart runs
        if (run_restart) then
 
            ! Read RESTART namelist
            call read_res_nml(res)
 
            ! Update grid-loop start values
            if (trim(p_system) == 'QHO') then
                alpha_start = res%i_qoi
            else 
                bond_start = res%i_qoi
                if (res%auto) then
                    ! For auto-search routines
                    auto_start = res%i_par
                else 
                    ! For grid-search routines
                    grid_start = res%i_par
                endif
 
            endif
 
            ! Print restarts header.
            if (my_rank==0) then
                write(*, "('------------- Restarted Program -------------')")
                write(*, "('')")
            endif
 
        end if 
 
 
    end subroutine read_inputs
 
    
end module input_parser